Aspect of the Turtle Cancelaura

The game's built-in re-press cancel has a grace period. This skips it, letting you activate and then immediately cancel Turtle. Do NOT use this if you spam Turtle, it needs deliberate single key presses to toggle on and off.

#showtooltip Aspect of the Turtle
/stopcasting
/stopcasting
/use Aspect of the Turtle
/cancelaura Aspect of the Turtle

Auto Kick / Stun

Uses your interrupt on a random casting target with no targeting, mouseover, or focus needed. Great for lower or uncoordinated keys: see a cast, hit the macro. The third version does the same for Intimidation.

It prefers kicking your focus if you have one. To prefer your mouseover instead, swap "focus" for "mouseover".

Counter ShotCopy

#showtooltip Counter Shot
/cast [@focus,exists,nodead,harm] Counter Shot
/stopmacro [@focus,exists,nodead,harm]
/focus target
/cleartarget
/targetenemy
/cast Counter Shot
/target focus
/clearfocus
/startattack

MuzzleCopy

#showtooltip Muzzle
/cast [@focus,exists,nodead,harm] Muzzle
/stopmacro [@focus,exists,nodead,harm]
/focus target
/cleartarget
/targetenemy
/cast Muzzle
/target focus
/clearfocus
/startattack

IntimidationCopy

#showtooltip
/cast [@focus,exists,nodead,harm] Intimidation
/stopmacro [@focus,exists,nodead,harm]
/focus target
/cleartarget
/targetenemy
/cast Intimidation
/target focus
/clearfocus
/startattack

Cursor Cast (ground-targeted abilities)

Skips the green targeting circle for ground-targeted abilities. I use it for Flare, Traps, Binding Shot, and Volley. Just place your cursor where you want it.

Freezing TrapCopy

#showtooltip
/use [@cursor]Freezing Trap

Tar TrapCopy

#showtooltip
/use [@cursor]Tar Trap

Binding ShotCopy

#showtooltip
/use [@cursor]Binding Shot

VolleyCopy

#showtooltip
/use [@cursor]Volley

FlareCopy

#showtooltip
/use [@cursor]Flare

Disengage StopCasting

Stops casts like Steady Shot and forces a Disengage, but will not cancel channels like Rapid Fire or Boomstick that you can actually Disengage in the middle of.

#showtooltip Disengage
/stopcasting [nochanneling:rapid fire,nochanneling:boomstick]
/stopcasting [nochanneling:rapid fire,nochanneling:boomstick]
/use Disengage

Focus Mouseover

Essential for serious Mythic+. Sets your mouseover as your focus and marks it with a green marker (unless it already has one), so the kick macros below can hit it.

/focus [@mouseover,exists,nodead][]
/tm [@mouseover,exists,nodead][] 4

Mouseover Master's Call

Casts Master's Call on your mouseover if it's a friendly, living target, otherwise on yourself.

#showtooltip
/use [@mouseover,help,nodead][@player]Master's Call(Cunning Ability)

Mouseover Multi-Shot

Mainly for MM, which may want to Multi-Shot something separate from its main target just to activate Trick Shots, but it works fine for BM too so I recommend it for both. The stopmacro line is there to protect your Rapid Fire channel from being cancelled when spamming your keys. MM Sentinel should take it out for AoE, where clipping the end of a Rapid Fire channel with Multi-Shot spreads Sentinel's Mark and is a DPS gain.

#showtooltip Multi-Shot
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm,nodead][]Multi-Shot
/petattack
/petassist

Mouseover Tranq Shot

Tranqs your mouseover enemy, or your target if there is no valid mouseover.

#showtooltip
/use [@mouseover,exists,harm,nodead][]Tranquilizing Shot

Pet Reset

Useful when jumping off ledges where you really want your pet to follow. Petpassive and petfollow make the pet snap to you more readily; the Dash line gets it back to you as fast as possible.

/petpassive
/petfollow
/use Dash

Pet Taunt

In Mythic+ it can be useful to taunt a powerful mob right before a tank buster to help save your tank. Use a Beetle, Boar, Carapid (BM only), Core Hound (BM only), Mechanical, Scalehide, Shale Beast (BM only), or Turtle, they have a 50% DR on a 1-min CD.

#showtooltip
/use [@mouseover,exists,harm][@focus,exists,harm]Growl
/use Scale Shield
/use Harden Carapace
/use Bristle
/use Bulwark
/use Obsidian Skin
/use Defense Matrix
/use Solid Shell
/use Shell Shield

Smart Misdirection (WeakAura / AddOn)

Automatically Misdirects the tank in your group, no targeting or focusing needed. Grab the TankMD addon, set up the macro below, and put it on your bars.

#showtooltip Misdirection
/click TankMDButton1

Auto Pet-Summon Kill Command

Summons or resurrects your pet if you don't have one out, otherwise it's a normal Kill Command. Set the Call Pet number to your default pet; when Lusting I swap it to my Lust pet's number so a mid-key death still summons the right pet. The res part isn't 100% reliable if the pet unit isn't present, so keep Revive Pet bound separately too.

#showtooltip Kill Command
/petassist
/petattack
/cast [@pet,dead] Revive Pet;
/cast [@pet,noexists,mod:shift] Revive Pet;
/cast [@pet,noexists] Call Pet 1;
/cast Kill Command

Bestial Wrath Cancelaura (Shroud/Camo)

Opening Bestial Wrath from Camo or Shroud in Pack Leader can glitch out Howl of the Pack Leader and stop your beasts spawning, a big DPS loss. This macro makes sure that can't happen.

#showtooltip
/cancelaura Shroud of Concealment
/cancelaura Camouflage
/use Bestial Wrath

Black Arrow Cancelaura + Mouseover

Same glitch can happen with Black Arrow and Deathblow procs. This also prefers your mouseover for Black Arrow, essential for the many cases where you can Black Arrow a secondary target but not your main one, or want to hit a prio target that's currently out of AoE position. The nochanneling line is an MM addition that stops the cast cancelling Rapid Fire prematurely.

#showtooltip Black Arrow
/cancelaura Shroud of Concealment
/cancelaura Camouflage
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Black Arrow

Nochanneling Ability Macros

Most offensive abilities should carry a nochanneling Rapid Fire clause so that no matter how hard you spam, you never clip or cancel your Rapid Fire channel by accident. The one deliberate clip left is MM Sentinel's Multi-Shot on AoE, so leave the nochanneling off that one. Here's how to do it across the kit.

Do not use the Arcane Shot, Kill Shot, Multi-Shot or Black Arrow versions atm. Clipping the end of a Rapid Fire channel with a Precise Shots spender is a DPS gain right now, so blocking the cast costs you damage. Everything else on this list is fine.

Aimed ShotCopy

#showtooltip
/petattack
/use [nochanneling:Rapid Fire]Aimed Shot

Arcane ShotCopy

#showtooltip
/petattack
/use [nochanneling:Rapid Fire]Arcane Shot

Kill ShotCopy

#showtooltip Kill Shot
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Kill Shot

Black ArrowCopy

#showtooltip Black Arrow
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Black Arrow

Explosive ShotCopy

#showtooltip Explosive Shot
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Explosive Shot

Multi-ShotCopy

#showtooltip
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,exists,harm][]Multi-Shot
/petattack
/petassist

Hunter's MarkCopy

#showtooltip
/stopmacro [channeling:Rapid Fire]
/use [@mouseover,harm,exists,nodead][]Hunter's Mark

Rapid FireCopy

#showtooltip
/use [nochanneling:Rapid Fire]Rapid Fire

Steady ShotCopy

#showtooltip Steady Shot
/use [nochanneling:Rapid Fire]Steady Shot

VolleyCopy

#showtooltip Volley
/stopmacro [channeling:Rapid Fire]
/use [@cursor]Volley

Trueshot + racialsCopy

#showtooltip
/stopmacro [channeling:Rapid Fire]
/use Trueshot
/use Blood Fury
/use Berserking
/use Ancestral Call(Racial)

Tab-Target Multi-Shot

Casts Multi-Shot on another enemy and puts you straight back on your current target. Spending a Precise Shots proc rolls for a Mark on whatever you have targeted, and a roll on a mob that already has one is wasted, so you want each one going onto a fresh target.

/targetenemy will not pick up mobs behind you or out of line of sight, so for those you still want the Mouseover Multi-Shot macro.

#showtooltip Multi-Shot
/targetenemy
/cast Multi-Shot
/targetlasttarget
/petattack
/petassist

Harpoon Mouseover

For quick position changes to a specific target without changing your DPS target. Also just feels cool af.

#showtooltip
/use [@mouseover,exists,harm][]harpoon
/cancelaura Updraft

Nochanneling Ability Macros

Every offensive ability should carry a nochanneling Boomstick clause so that no matter how hard you spam, you never clip or cancel your Boomstick channel. Here's how to do it across the kit.

Raptor StrikeCopy

#showtooltip
/petattack
/use [nochanneling:Boomstick]Raptor Strike

Kill CommandCopy

#showtooltip
/petattack
/use [nochanneling:Boomstick]Kill Command

Wildfire BombCopy

#showtooltip
/stopmacro [channeling:Boomstick]
/use [@mouseover,exists,harm][]Wildfire Bomb

BoomstickCopy

#showtooltip
/use [nochanneling:Boomstick]Boomstick

Takedown + racialsCopy

#showtooltip
/stopmacro [channeling:Boomstick]
/use Takedown
/use Blood Fury
/use Berserking
/use Ancestral Call(Racial)

Aspect of the EagleCopy

#showtooltip
/stopmacro [channeling:Boomstick]
/use Aspect of the Eagle
/use [nochanneling:Boomstick]Raptor Strike

Wildfire Bomb Mouseover

Wildfire Bomb is both a cone behind your target and a circle around it. In spread AoE you may have to rely on the cone alone, and mouseover Bombing is extremely potent for maximizing coverage.

#showtooltip Wildfire Bomb
/petattack
/use [@mouseover,harm,nodead,exists][]Wildfire Bomb